@echo off

REM HINT1=http://qiita.com/usagi/items/2623145f22faf54b99e0
REM HINT2=http://qiita.com/jTakasuRyuji/items/e7bd576ed57969b2d06e

cd %~dp0

:checkMandatoryLevel
REM ▼管理者として実行されているか確認 START
for /f "tokens=1 delims=," %%i in ('whoami /groups /FO CSV /NH') do (
    if "%%~i"=="BUILTIN\Administrators" set ADMIN=yes
    if "%%~i"=="Mandatory Label\High Mandatory Level" set ELEVATED=yes
)

if "%ADMIN%" neq "yes" (
    echo Administratorsグループに属するユーザーが、このファイルを実行してください。
    echo To run this batch file, current user must belong to the administrative user group.
   if "%1" neq "/R" goto runas
   goto exit1
)
if "%ELEVATED%" neq "yes" (
    echo このファイルは管理者権限での実行が必要です。「管理者として実行」してください。
    echo You need to run this batch file as Administrator.
   if "%1" neq "/R" goto runas
   goto exit1
)
REM ▲管理者として実行されているか確認 END


:admins
    REM ▼管理者として実行したいコマンド START

    "C:\Windows\Microsoft.NET\Framework\v4.0.30319\ngen.exe" install DTXCreator.exe
    "C:\Windows\Microsoft.NET\Framework\v4.0.30319\ngen.exe" install DTXManiaGR.exe

    REM ▲管理者として実行したいコマンド END
    goto exit1

:runas
    REM ★管理者として再実行 (ここの注釈部を有効にすると、再帰的に自動昇格する)
    REM powershell -Command Start-Process -Verb runas "%0" -ArgumentList "/R" 

:exit1
PAUSE

