# Frequently Asked Questions (FAQ)

#### Language Syntax

- When are quotation marks used with commands and their parameters?
- When exactly are variable names enclosed in percent signs?
- When should percent signs and commas be escaped?

#### Common Tasks

- Why do some lines in my script never execute?
- Why is the Run command unable to launch my game or program?
- How can the output of a command line operation be retrieved?
- How can a script close, pause, or suspend other script(s)?
- How can a repeating action be stopped without exiting the script?
- How can performance be improved for games or at other times when the CPU is under heavy load?
- How can context sensitive help for AutoHotkey commands be used in any editor?
- How to detect when a web page is finished loading?
- How can dates and times be compared or manipulated?
- Why don't Hotstrings, Send, and MouseClick work in certain games?
- How can Winamp be controlled even when it isn't active?
- How can MsgBox's button names be changed?

#### Hotkeys, Hotstrings, and Remapping

- How do I put my hotkeys and hotstrings into effect automatically every time I start my PC?
- I'm having trouble getting my mouse buttons working as hotkeys. Any advice?
- How can tab and space be defined as hotkeys?
- How can keys or mouse buttons be remapped so that they become different keys?
- How can a hotkey or hotstring be made exclusive to certain program(s)? In other words, I want a certain key to act as it normally does except when a specific window is active.
- How can a prefix key be made to perform its native function rather than doing nothing?
- How can the built-in Windows shortcut keys, such as Win+U (Utility Manager) and Win+R (Run), be changed or disabled?
- My keypad has a special 000 key. Is it possible to turn it into a hotkey?

## Language Syntax

#### When are quotation marks used with commands and their parameters?

Double quotes (") have special meaning only within expressions. In all other places, they are treated literally as if they were normal characters. However, when a script launches a program or document, the operating system usually requires quotes around any command-line parameter that contains spaces, such as in this example: Run, Notepad.exe "C:\My Documents\Address List.txt"

#### When exactly are variable names enclosed in percent signs?

Variable names are always enclosed in percent signs except in cases illustrated in bold below:

1) In parameters that are input or output variables: StringLen, OutputVar, InputVar
2) On the left side of an assignment: Var = 123abc
3) On the left side of traditional (non-expression) if-statements: If Var1 < %Var2%
4) Everywhere in expressions. For example:
If (Var1 <> Var2)
Var1 := Var2 + 100

#### When should percent signs and commas be escaped?

Literal percent signs must be escaped by preceding them with an accent/backtick. For example: MsgBox The current percentage is 25`%. Literal commas must also be escaped (`,) except when used in MsgBox or the last parameter of any command (in which case the accent is permitted but not necessary).

When commas or percent signs are enclosed in quotes within an expression, the accent is permitted but not necessary. For example: Var := "15%"

## Common Tasks

#### Why do some lines in my script never execute?

Any lines you want to execute immediately when the script starts should appear at the top of the script, prior to the first hotkey, hotstring, or Return. For details, see auto-execute section.

Also, a hotkey that executes more than one line must list its first line beneath the hotkey, not on the same line. For example:

    #space::  ; Win+Spacebar
    Run Notepad
    WinWaitActive Untitled - Notepad
    WinMaximize
    return

#### Why is the Run command unable to launch my game or program?

Some programs need to be started in their own directories (when in doubt, it is usually best to do so). For example:
Run, %A_ProgramFiles%\Some Application\App.exe, %A_ProgramFiles%\Some Application

#### How can the output of a command line operation be retrieved?

Testing shows that due to file caching, a temporary file can be very fast for relatively small outputs. In fact, if the file is deleted immediately after use, it often does not actually get written to disk. For example:

    RunWait %comspec% /c dir > C:\My Temp File.txt
    FileRead, VarToContainContents, C:\My Temp File.txt
    FileDelete, C:\My Temp File.txt

To avoid using a temporary file (especially if the output is large), consider using CmdRet. Alternatively, there is a small freeware utility cb.zip (4 KB) that captures up to 512 KB of output from a command or program. The text is captured to the clipboard, which a script can access via the clipboard variable. For example:

    RunWait %comspec% /c dir | cb.exe
    MsgBox %clipboard%

#### How can a script close, pause, or suspend other script(s)?

First, here is an example that closes another script:

    DetectHiddenWindows On  ; Allows a script's hidden main window to be detected.
    SetTitleMatchMode 2  ; Avoids the need to specify the full path of the file below.
    WinClose Script's File Name.ahk - AutoHotkey  ; Update this to reflect the script's name (case sensitive).

To suspend or pause another script, replace the last line above with one of these:

    PostMessage, 0x111, 65305,,, Script's File Name.ahk - AutoHotkey  ; Suspend.
    PostMessage, 0x111, 65306,,, Script's File Name.ahk - AutoHotkey  ; Pause.

#### How can a repeating action be stopped without exiting the script?

To pause or resume the entire script at the press of a key, assign a hotkey to the Pause command as in this example:

    ^!p::Pause  ; Press Ctrl+Alt+P to pause. Press it again to resume.

To stop an action that is repeating inside a Loop, consider the following working example, which is a hotkey that both starts and stops its own repeating action. In other words, pressing the hotkey once will start the Loop. Pressing the same hotkey again will stop it.

    #MaxThreadsPerHotkey 3
    #z::  ; Win+Z hotkey (change this hotkey to suit your preferences).
    #MaxThreadsPerHotkey 1
    if KeepWinZRunning  ; This means an underlying thread is already running the loop below.
    {
        KeepWinZRunning := false  ; Signal that thread's loop to stop.
        return  ; End this thread so that the one underneath will resume and see the change made by the line above.
    }
    ; Otherwise:
    KeepWinZRunning := true
    Loop
    {
        ; The next four lines are the action you want to repeat (update them to suit your preferences):
        ToolTip, Press Win-Z again to stop this from flashing.
        Sleep 1000
        ToolTip
        Sleep 1000
        ; But leave the rest below unchanged.
        if not KeepWinZRunning  ; The user signaled the loop to stop by pressing Win-Z again.
            break  ; Break out of this loop.
    }
    KeepWinZRunning := false  ; Reset in preparation for the next press of this hotkey.
    return

#### How can performance be improved for games or at other times when the CPU is under heavy load?

If a script's Hotkeys, Clicks, or Sends are noticeably slower than normal while the CPU is under heavy load, raising the script's process-priority may help. To do this, include the following line near the top of the script:
Process, Priority, , High

#### How can context sensitive help for AutoHotkey commands be used in any editor?

Rajat created this script.

#### How to detect when a web page is finished loading?

With Internet Explorer, perhaps the most reliable method is to use DllCall and COM as demonstrated at www.autohotkey.com/forum/topic19256.html. On a related note, the contents of the address bar and status bar can be retrieved as demonstrated at www.autohotkey.com/forum/topic19255.html.

Older, less reliable method: The technique in the following example will work with MS Internet Explorer for most pages. A similar technique might work in other browsers:

    Run, www.yahoo.com
    MouseMove, 0, 0  ; Prevents the status bar from showing a mouse-hover link instead of "Done".
    WinWait, Yahoo! -
    WinActivate
    StatusBarWait, Done, 30
    if ErrorLevel
       MsgBox The wait timed out or the window was closed.
    else
       MsgBox The page is done loading.

#### How can dates and times be compared or manipulated?

The EnvAdd command can add or subtract a quantity of days, hours, minutes, or seconds to a time-string that is in the YYYYMMDDHH24MISS format. The following example subtracts 7 days from the specified time:
EnvAdd, VarContainingTimestamp, -7, days

To determine the amount of time between two dates or times, see EnvSub, which gives an example. Also, the built-in variable A_Now contains the current local time. Finally, there are several built-in date/time variables, as well as the FormatTime command to create a custom date/time string.

#### Why do Hotstrings, Send, and Click have no effect in certain games?

Some games use DirectInput exclusively. As a side-effect, they might ignore all simulated keystrokes and mouse clicks. To work around this, try one of the following (or a combination):

- Use SendPlay via: 1) the SendPlay command; 2) using SendMode Play; and/or 3) the hotstring option SP.
- Increase SetKeyDelay. For example:
  SetKeyDelay, 0, 50
  SetKeyDelay, 0, 50, Play
- Try ControlSend, which might work in cases where the other Send modes fail.

#### How can Winamp be controlled even when it isn't active?

See Automating Winamp.

#### How can MsgBox's button names be changed?

Here is an example.

## Hotkeys, Hotstrings, and Remapping

#### How do I put my hotkeys and hotstrings into effect automatically every time I start my PC?

There is a folder in the Start Menu called Startup. If you put a shortcut to your script in that folder, the script will launch automatically every time you start your PC. To create a shortcut:

1. Find the script file, select it, and press Control-C.
2. Right-click the Start button (typically at the lower left corner of the screen) and choose "Explore All Users".
3. Navigate to the Startup folder inside the Programs folder.
4. From the menu bar, choose Edit -> Paste Shortcut. The shortcut to the script should now be in the Startup folder.

#### I'm having trouble getting my mouse buttons working as hotkeys. Any advice?

Note that mouse hotkeys are not currently possible on Windows 95/98/Me. On other operating systems, the left and right mouse buttons should be assignable normally (for example, "#LButton::" is the Win+LeftButton hotkey). Similarly, the middle button and the turning of the mouse wheel should be assignable normally except on mice whose drivers directly control those buttons.

The fourth button (XButton1) and the fifth button (XButton2) might be assignable if your mouse driver allows their clicks to be seen by the system. If they cannot be seen -- or if your mouse has more than five buttons that you want to use -- you can try configuring the software that came with the mouse (sometimes accessible in the Control Panel or Start Menu) to send a keystroke whenever you press one of these buttons. Such a keystroke can then be defined as a hotkey in a script. For example, if you configure the fourth button to send Control+F1, you can then indirectly configure that button as a hotkey by using ^F1:: in a script.

If you have a five-button mouse whose fourth and fifth buttons cannot be seen, you can try changing your mouse driver to the default driver included with the OS. This assumes there is such a driver for your particular mouse and that you can live without the features provided by your mouse's custom software.

#### How can Tab and Space be defined as hotkeys?

Use the names of the keys (Tab and Space) rather than their characters. For example, #Space is Win+Space and ^!Tab is Control+Alt+Tab.

#### How can keys or mouse buttons be remapped so that they become different keys?

This is described on the remapping page.

#### How can a hotkey or hotstring be made exclusive to certain program(s)? In other words, I want a certain key to act as it normally does except when a specific window is active.

The preferred method is #IfWinActive. For example:

    #IfWinActive, ahk_class Notepad
    ^a::MsgBox You pressed Control-A while Notepad is active.

Windows 95/98/Me: Although the above method works, pressing Control-A in a window other than Notepad will do nothing at all (not even its native function). To work around this, use:

    $^a::Send ^a  ; This hotkey must be listed first on Windows 9x. The $ prefix allows it to "send itself".
    #IfWinActive, ahk_class Notepad
    ^a::MsgBox You pressed Control-A while Notepad is active.

#### How can a prefix key be made to perform its native function rather than doing nothing?

Consider the following example, which makes Numpad0 into a prefix key:

    Numpad0 & Numpad1::MsgBox, You pressed Numpad1 while holding down Numpad0.

Now, to make Numpad0 send a real Numpad0 keystroke whenever it wasn't used to launch a hotkey such as the above, add the following hotkey:

     $Numpad0::Send, {Numpad0}

The $ prefix is needed to prevent a warning dialog about an infinite loop (since the hotkey "sends itself"). In addition, the above action occurs at the time the key is released.

#### How can the built-in Windows shortcut keys, such as Win+U (Utility Manager) and Win+R (Run), be changed or disabled?

Here are some examples.

#### My keypad has a special 000 key. Is it possible to turn it into a hotkey?

You can, but only if you're running Windows NT, 2000, XP, or beyond. This example script makes the 000 key into an equals key. You can change the action by replacing the "Send, =" line with line(s) of your choice.