# IfWinExist / IfWinNotExist

Checks if the specified window exists.

IfWinExist [, WinTitle, WinText, ExcludeTitle, ExcludeText]
IfWinNotExist [, WinTitle, WinText, ExcludeTitle, ExcludeText]
UniqueID := WinExist("WinTitle", "WinText", "ExcludeTitle", "ExcludeText")

#### Parameters

WinTitle | The title or partial title of the target window (the matching behavior is determined by SetTitleMatchMode). If this and the other 3 parameters are all omitted, the Last Found Window will be used (i.e. that specific window is checked to see whether it still exists). If this is the letter A and the other 3 parameters are omitted, the active window will be used. To use a window class, specify ahk_class ExactClassName (shown by Window Spy). To use a process identifier (PID), specify ahk_pid %VarContainingPID%. To use a window group, specify ahk_group GroupName. To use a window's unique ID number, specify ahk_id %VarContainingID%. The search can be narrowed by specifying multiple criteria. For example: My File.txt ahk_class Notepad
WinText | If present, this parameter must be a substring from a single text element of the target window (as revealed by the included Window Spy utility). Hidden text elements are detected if DetectHiddenText is ON.
ExcludeTitle | Windows whose titles include this value will not be considered. Note: Due to backward compatibility with .aut scripts, this parameter will be interpreted as a command if it exactly matches the name of a command. To work around this, use the WinExist() function instead.
ExcludeText | Windows whose text include this value will not be considered.

#### Remarks

If all parameters are omitted, the Last Found Window will be checked to see if it still exists (or doesn't exist in the case of IfWinNotExist).

If either of these commands determines that a qualified window exists, the Last Found Window will be updated to be that window. In other words, if IfWinExist evaluates to true or IfWinNotExist evaluates to false, the Last Found Window will be updated.

The function WinExist() returns the Unique ID (HWND) of the first matching window (0 if none). Since all non-zero numbers are seen as "true", the statement if WinExist("WinTitle") is true whenever WinTitle exists.

To discover the HWND of a control (for use with Post/SendMessage or DllCall), use ControlGet Hwnd or MouseGetPos.

SetWinDelay does not apply to IfWinExist/IfWinActive.

Window titles and text are case sensitive. Hidden windows are not detected unless DetectHiddenWindows has been turned on.

#### Related

IfWinActive, SetTitleMatchMode, DetectHiddenWindows, Last Found Window, Process, WinActivate, WinWaitActive, WinWait, WinWaitClose, #IfWinActive/Exist

#### Examples

    IfWinExist, Untitled - Notepad
    {
        WinActivate  ; Automatically uses the window found above.
        WinMaximize  ; same
        Send, Some text.{Enter}
        return
    }

    IfWinNotExist, Calculator
        return
    else
    {
        WinActivate  ; The above "IfWinNotExist" also set the "last found" window for us.
        WinMove, 40, 40  ; Move it to a new position.
        return
    }

    if WinExist("ahk_class Notepad") or WinExist("ahk_class" . ClassName)
        WinActivate  ; Uses the last found window.

    MsgBox % "The active window's ID is " . WinExist("A")