# IfWinActive / IfWinNotActive

Checks if the specified window exists and is currently active (foremost).

IfWinActive [, WinTitle, WinText, ExcludeTitle, ExcludeText]
IfWinNotActive [, WinTitle, WinText, ExcludeTitle, ExcludeText]
UniqueID := WinActive("WinTitle", "WinText", "ExcludeTitle", "ExcludeText")

#### Parameters

WinTitle | The title or partial title of the target window (the matching behavior is determined by SetTitleMatchMode). If this and the other 3 parameters are omitted, the Last Found Window will be used. To use a window class, specify ahk_class ExactClassName (shown by Window Spy). To use a process identifier (PID), specify ahk_pid %VarContainingPID%. To use a window group, specify ahk_group GroupName. To use a window's unique ID number, specify ahk_id %VarContainingID%. The search can be narrowed by specifying multiple criteria. For example: My File.txt ahk_class Notepad
WinText | If present, this parameter must be a substring from a single text element of the target window (as revealed by the included Window Spy utility). Hidden text elements are detected if DetectHiddenText is ON.
ExcludeTitle | Windows whose titles include this value will not be considered. Note: Due to backward compatibility with .aut scripts, this parameter will be interpreted as a command if it exactly matches the name of a command. To work around this, use the WinActive() function instead.
ExcludeText | Windows whose text include this value will not be considered.

#### Remarks

If all parameters are omitted, the Last Found Window will be used.

If either of these commands determines that the active window is a qualified match, the Last Found Window will be updated to be the active window. In other words, if IfWinActive evaluates to "true" or IfWinNotActive evaluates to "false", the Last Found Window will be updated.

The function WinActive() returns the Unique ID (HWND) of the active window if it matches the specified criteria. If it does not, the function returns 0. Since all non-zero numbers are seen as "true", the statement if WinActive("WinTitle") is true whenever WinTitle is active.

SetWinDelay does not apply to IfWinExist/IfWinActive.

Window titles and text are case sensitive. Hidden windows are not detected unless DetectHiddenWindows has been turned on.

#### Related

IfWinExist, SetTitleMatchMode, DetectHiddenWindows, Last Found Window, WinActivate, WinWaitActive, WinWait, WinWaitClose, #IfWinActive/Exist

#### Example

    IfWinActive, Untitled - Notepad
    {
        WinMaximize  ; Maximizes the Notepad window found by IfWinActive above.
        Send, Some text.{Enter}
        return
    }

    if WinActive("ahk_class Notepad") or WinActive("ahk_class" . ClassName)  ; "ahk_class" need not have a space after it.
        WinClose  ; Uses the last found window.