# WinGetPos

Retrieves the position and size of the specified window.

WinGetPos [, X, Y, Width, Height, WinTitle, WinText, ExcludeTitle, ExcludeText]

#### Parameters

X, Y | The names of the variables in which to store the X and Y coordinates of the target window's upper left corner. If omitted, the corresponding values will not be stored.
Width/Height | The names of the variables in which to store the width and height of the target window. If omitted, the corresponding values will not be stored.
WinTitle | The title or partial title of the target window (the matching behavior is determined by SetTitleMatchMode). If this and the next 3 parameters are omitted, the Last Found Window will be used. If this is the letter A and the next 3 parameters are omitted, the active window will be used. To use a window class, specify ahk_class ExactClassName (shown by Window Spy). To use a process identifier (PID), specify ahk_pid %VarContainingPID%. To use a window group, specify ahk_group GroupName. To use a window's unique ID number, specify ahk_id %VarContainingID%. The search can be narrowed by specifying multiple criteria. For example: My File.txt ahk_class Notepad
WinText | If present, this parameter must be a substring from a single text element of the target window (as revealed by the included Window Spy utility). Hidden text elements are detected if DetectHiddenText is ON.
ExcludeTitle | Windows whose titles include this value will not be considered.
ExcludeText | Windows whose text include this value will not be considered.

#### Remarks

If no matching window is found, the output variables will be made blank.

If the WinTitle Program Manager is used, the command will retrieve the size of the desktop, which is usually the same as the current screen resolution.

A minimized window will still have a position and size. The values returned in this case may vary depending on OS and configuration.

To discover the name of the window and control that the mouse is currently hovering over, use MouseGetPos.

Window titles and text are case sensitive. Hidden windows are not detected unless DetectHiddenWindows has been turned on.

#### Related

WinMove, ControlGetPos, WinGetActiveStats, WinGetActiveTitle, WinGetTitle, WinGetText, ControlGetText

#### Example

    WinGetPos, X, Y, Width, Height, Calculator
    MsgBox, Calculator is at %X%`,%Y%

    WinGetPos, X, Y, , , A  ; "A" to get the active window's pos.
    MsgBox, The active window is at %X%`,%Y%

    IfWinExist, Untitled - Notepad
    {
        WinGetPos, Xpos, Ypos  ; Uses the window found above.
        MsgBox, Notepad is at %Xpos%`,%Ypos%
    }