# Sleep

Waits the specified amount of time before continuing.

Sleep, DelayInMilliseconds

#### Parameters

Delay | The amount of time to pause (in milliseconds) between 0 and 2147483647 (24 days), which can be an expression.

#### Remarks

Due to the granularity of the OS's time-keeping system, Delay is typically rounded up to the nearest multiple of 10 or 15.6 milliseconds (depending on the type of hardware and drivers installed). For example, a delay between 1 and 10 (inclusive) is equivalent to 10 or 15.6 on most Windows NT/2000/XP systems. To achieve a shorter delay, see Examples.

The actual delay time might wind up being longer than what was requested if the CPU is under load. This is because the OS gives each needy process a slice of CPU time (typically 20 milliseconds) before giving another timeslice to the script.

A delay of 0 yields the remainder of the script's current timeslice to any other processes that need it (as long as they are not significantly lower in priority than the script). Thus, a delay of 0 produces an actual delay between 0 and 20ms (or more), depending on the number of needy processes (if there are no needy processes, there will be no delay at all). However, a Delay of 0 should always wind up being shorter than any longer Delay would have been.

While sleeping, new threads can be launched via hotkey, custom menu item, or timer.

"Sleep -1": A delay of -1 does not sleep but instead makes the script immediately check its message queue. This can be used to force any pending interruptions to occur at a specific place rather than somewhere more random. See Critical for more details.

#### Related

SetKeyDelay, SetMouseDelay, SetControlDelay, SetWinDelay, SetBatchLines

#### Examples

    Sleep, 1000  ; 1 second

    ; The following is a working example that demonstrates how to sleep for less time than the
    ; normal 10 or 15.6 milliseconds.
    ; NOTE: While a script like this is running, the entire operating system and all applications are
    ; affected by timeBeginPeriod below.

    SetBatchLines -1  ; Ensures maximum effectiveness of this method.

    SleepDuration = 1  ; This can sometimes be finely adjusted (e.g. 2 is different than 3) depending on the value below.
    TimePeriod = 3 ; Try 7 or 3.  See comment below.
    ; On a PC whose sleep duration normally rounds up to 15.6 ms, try TimePeriod=7 to allow
    ; somewhat shorter sleeps, and try TimePeriod=3 or less to allow the shortest possible sleeps.

    DllCall("Winmm\timeBeginPeriod", uint, TimePeriod)  ; Affects all applications, not just this script's DllCall("Sleep"...), but does not affect SetTimer.
    Iterations = 50
    StartTime := A_TickCount

    Loop %Iterations%
        DllCall("Sleep", UInt, SleepDuration)  ; Must use DllCall instead of the Sleep command.

    DllCall("Winmm\timeEndPeriod", UInt, TimePeriod)  ; Should be called to restore system to normal.
    MsgBox % "Sleep duration = " . (A_TickCount - StartTime) / Iterations