# PostMessage / SendMessage

发送一条消息给一个窗口或一个控件 (SendMessage 还会等待回应)。

PostMessage, Msg [, wParam, lParam, Control, WinTitle, WinText, ExcludeTitle, ExcludeText]
SendMessage, Msg [, wParam, lParam, Control, WinTitle, WinText, ExcludeTitle, ExcludeText]

#### 参数

Msg | 需要发送的消息码，可以是一个 表达式。参看 消息列表 以确定数值。
wParam | 消息的第一个参数，可以是一个 表达式。如果为空或省略，将会发送 0。
lParam | 消息的第二个参数，可以是一个 表达式。如果为空或省略，将会发送 0。
Control | 如果此参数为空或省略，消息将被直接发送给目标窗口，而不是它的某个控件。否则，这个参数可以是 ClassNN (控件的类名和实例号) 或者控件的 名字/文本，两者都可通过 Window Spy 来确定。使用 名字/文本 时，匹配模式由 SetTitleMatchMode 决定。 若要通过控件的 HWND (窗口句柄) 来操作，则将 Control 参数留空并为 WinTitle 参数指定 ahk_id %ControlHwnd% (也适用于隐藏控件，即使 DetectHiddenWindows 为 Off)。一个控件的 HWND 通常可以通过 ControlGet Hwnd, MouseGetPos, 或 DllCall 来获取。
WinTitle | 目标窗口的部分或整个标题 (匹配模式由 SetTitleMatchMode 决定)。如果省略这个和另外3个参数，将使用 上一次匹配窗口 。如果这个参数为字母 A 且省略其他3个参数，将使用当前激活的窗口。要使用窗口类，指定 ahk_class 精确的类名 (Window Spy可以显示类名)。要使用 进程标识符 (PID)，指定 ahk_pid %PID变量%。要使用 窗口组，指定 ahk_group 组名。要使用窗口的 唯一ID，指定 ahk_id %ID变量% (也接受 控件的 HWND)。要减小检测范围，使用指定 多重条件。例如：My File.txt ahk_class Notepad
WinText | 如果使用这个参数，则它应该是目标窗口中某个文本元素的子字符串（在 Window Spy 中会显示出窗口中的文本元素）。隐藏文本只有在 DetectHiddenText 设置为 ON 的时候才能检测到。
ExcludeTitle | 标题含有此参数值的窗口将不被考虑。
ExcludeText | 文本含有此参数值的窗口将不被考虑。

#### ErrorLevel

PostMessage: 如果出现问题，例如目标窗口或控件不存在， ErrorLevel 会被设为 1。否则为 0。

SendMessage: 如果出现问题，ErrorLevel 会被设为单词 FAIL。否则，会被设为此消息的数值结果，有时可能是一个根据消息的类型和消息的目标窗口的类型而决定的一个“回覆 (reply) ”。这个结果是一个 0 与 4294967295 之间的整数。如果结果应该是有符号的，下列例子可以将负数结果展现出来：MsgReply := ErrorLevel > 0x7FFFFFFF ? -(~ErrorLevel) - 1 : ErrorLevel

#### 注意

应该小心使用这些命令。因为发送一条消息到错误的窗口（或发送无效的消息）可能导致不可预料的行为，甚至使目标应用程序崩溃。这是因为多数应用程序在设计时并不会考虑对某些从外部来源发来的消息做处理。

PostMessage 将消息放置到与目标窗口相关的消息队列中。它不会等待回应或答覆。相比之下，SendMessage 会用最多5秒钟来等待目标窗口处理此消息。如果消息在这段时间内未处理完，此命令结束并设置 ErrorLevel 为单词 FAIL 。

参数 Msg, wParam, 与 lParam 都应该是 -2147483648 与 4294967295 (0xFFFFFFFF) 之间的整数。AutoHotkey 中所有的整型数值，都可以附加前缀 0x 来代表一个十六进制值。例如， 0xFF 等于 255 。

若要通过 wParam 或 lParam 发送一个字符串，可以指定一个变量的地址。以下例子使用 取地址运算符 (&) 来完成此事：

    SendMessage, 0xC, 0, &MyVar, ClassNN, WinTitle  ; 0XC 是 WM_SETTEXT

在 v1.0.43.06 及以后的版本中，消息的接收者放置在 MyVar 中的字符串可以被正确辨认，无需附加步骤。不过这只有在参数的第一个字符是一个 与符号(&) 时才可以。例如， 5+&MyVar 不行但是 &MyVar 或 &MyVar+5 就可以。

一个 带引号/原意(quoted/literal) 的字符串也可以被发送。参照以下的可用范例（此种情况下不应该使用 & 操作符）：

    Run Notepad
    WinWait 无标题 - 记事本
    SendMessage, 0xC, 0, "新的记事本标题"  ; 0XC 是 WM_SETTEXT

要发送一条消息给系统中所有的窗口（包括隐藏或无效的），指定 WinTitle 为 ahk_id 0xFFFF （0xFFFF 是 HWND_BROADCAST）。此技巧应该只在专门用于广播的消息上使用。例如以下的范例：

    SendMessage, 0x1A,,,, ahk_id 0xFFFF  ; 0x1A 是 WM_SETTINGCHANGE

若想拥有能够接收消息的脚本，可以使用 OnMessage() 。

参看 消息指南 以获得使用这些命令的说明。

窗口标题与文本都是区分大小写的。隐藏窗口不会被检测，除非开启了 DetectHiddenWindows 。

#### 相关命令

消息列表, 消息指南, OnMessage(), 自动化 Winamp, DllCall, ControlSend, WinMenuSelectItem

#### 示例

    #o::  ; Win+O 热键关闭显示器。
    Sleep 1000  ; 给用户释放按键的机会（万一它们被释放会再次唤醒显示器）。
    ; 关闭显示器:
    SendMessage, 0x112, 0xF170, 2,, Program Manager  ; 0x112 是 WM_SYSCOMMAND, 0xF170 是 SC_MONITORPOWER。
    ; 上面的备注: 使用 -1 代替 2 可以打开显示器。
    ; 使用 1 代替 2 可以开启显示器的节能模式。
    return

    ; 启动用户选择的屏幕保护程序：
    SendMessage, 0x112, 0xF140, 0,, Program Manager  ; 0x112 是 WM_SYSCOMMAND, 0xF140 是 SC_SCREENSAVE。

    ; 向上滚动一行 (用于拥有垂直滚动条的控件)：
    ControlGetFocus, control, A
    SendMessage, 0x115, 0, 0, %control%, A

    ; 向下滚动一行：
    ControlGetFocus, control, A
    SendMessage, 0x115, 1, 0, %control%, A

    ; 切换活动窗口的 键盘布局/语言 到英语：
    PostMessage, 0x50, 0, 0x4090409,, A  ; 0x50 是 WM_INPUTLANGCHANGEREQUEST。

    ; 本示例询问 Winamp 当前活动的音轨号是哪一个：
    SetTitleMatchMode, 2
    SendMessage, 1024, 0, 120, - Winamp
    if ErrorLevel <> FAIL
    {
        ErrorLevel++  ; Winamp 的计数器从 "0" 开始，所以用 1 调整。
        MsgBox, 音轨 #%ErrorLevel% 是活动的或正在播放。.
    }
    ; 参看 自动化 Winamp 获得更多信息。

    ; 要查找一个 AHK脚本 的进程ID (另一个办法是 "WinGet PID"):
    SetTitleMatchMode, 2
    DetectHiddenWindows, on
    SendMessage, 0x44, 0x405, 0, , SomeOtherScript.ahk - AutoHotkey v
    MsgBox %ErrorLevel% 是进程 id。