# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Contributor: Alessio Sergi <asergi at archlinux dot us>

pkgname=synapse
pkgver=0.2.99.4
pkgrel=4
pkgdesc="A semantic file launcher"
arch=('x86_64')
url="https://launchpad.net/synapse-project"
license=('GPL3')
depends=('libkeybinder3' 'hicolor-icon-theme' 'json-glib' 'libgee' 'libnotify'
         'zeitgeist' 'xdg-utils')
makedepends=('intltool' 'vala')
optdepends=('bc: calculator plugin'
            'devhelp: documentation plugin'
            'gnome-dictionary: dictionary plugin'
            'openssh: ssh plugin'
            'pastebinit: pastebin plugin'
            'rhythmbox: rhythmbox plugin')
source=("https://launchpad.net/$pkgname-project/0.3/$pkgver/+download/$pkgname-$pkgver.tar.xz")
sha512sums=('d9668fb9dd18d97da89bf5f0a9864f843c629f91751b326b4e97de74c6db64a59dbcd221f1b6ed0fc199a683ed511d86f280756fe4c21195d6169d2977315325')

build() {
  cd "$srcdir/$pkgname-$pkgver"

  ./configure --prefix=/usr
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"

  make DESTDIR="$pkgdir/" install
}

# vim:set ts=2 sw=2 et:
